pkgname=ltsa
pkgver=3.0
pkgrel=4
pkgdesc="Labelled Transition System Analyser, a verification tool for concurrent systems"
arch=(any)
url="http://www.doc.ic.ac.uk/ltsa/"
license=('unknown')
depends=('java-runtime')
makedepends=('imagemagick')
source=('http://www.doc.ic.ac.uk/~jnm/book/ltsa/ltsatool.zip')
md5sums=('09afa4ffd87b1dfc4c84e1e20452ae09')

build() {
  cd "$srcdir"

  cat > "ltsa.sh" <<EOF
#!/bin/sh
exec java -jar /usr/share/ltsa/ltsa.jar
EOF

  cat > "ltsa.desktop" <<EOF
[Desktop Entry]
Type=Application
Version=1.0
Name=LTSA
Comment=Labelled Transition System Analyser,a verification tool for concurrent systems.
Exec=ltsa
Icon=ltsa.png
Terminal=false
Categories=Education;Java;
EOF

  convert "ltsatool/ltsa.ico" "ltsa.png"
}

package() {
  install -DT -m755 "$srcdir/ltsa.sh" "$pkgdir/usr/bin/ltsa"

  install -DT -m644 "$srcdir/ltsatool/ltsa.jar" "$pkgdir/usr/share/ltsa/ltsa.jar"
  install -DT -m644 "$srcdir/ltsatool/ltl2buchi.jar" "$pkgdir/usr/share/ltsa/ltl2buchi.jar"

  install -DT -m644 "$srcdir/ltsa.desktop" "$pkgdir/usr/share/applications/ltsa.desktop"

  install -DT -m644 "$srcdir/ltsa.png" "$pkgdir/usr/share/pixmaps/ltsa.png"

  mkdir -p "$pkgdir/usr/share/doc/ltsa"
  cp -r "$srcdir/ltsatool/Chapter_examples" "$pkgdir/usr/share/doc/ltsa/examples"
  for p in "$pkgdir/usr/share/doc/ltsa/"{**/*,*} ; do
    if [[ -d "$p" ]] ; then
      chmod 755 "$p"
    else
      chmod 644 "$p"
    fi
  done
}

# vim:set ts=2 sw=2 et: